Salut à tous !
J'ai créé un jeu où le joueur incarne un missile, qui peut se déplacer vers le haut ou vers le bas.
Le but du jeu est d'éviter le plus d'obstacles possibles (représentés par des points).
| Code | ZoomSto
StoreGDB 1
StorePic 1
RectGC
CoordOff
GridOff
AxesOff
LabelOff
ExprOff
PlotsOff
FnOff
ClrDraw
0→Xmin
0→Ymin
1→∆X
1→∆Y
0→Xscl
0→Yscl
Lbl ME
1→dim(⌊SMISS
3→dim(L₆
⌊SMISS(1→S
For(I,1,3
iPart(S→L₆(I
1000(S-L₆(I→S
End
Menu("MISSILE","JOUER",JO,"RECORDS",RE,"REGLES",RG,"QUITTER",QU
Lbl RE
For(I,0,2
Text(7I,0,I+1," : ",L₆(I+1
End
Pause
ClrDraw
Goto ME
Lbl RG
Text(0,0,"LE BUT DU JEU EST DE
Text(7,0,"DEPLACER LA FUSEE AVEC LES
Text(14,0,"FLECHES HAUT ET BAS, AFIN
Text(21,0,"D'EVITER DE SE FAIRE
Text(28,0,"TOUCHER PAR UN MISSILE.
Pause
ClrDraw
Goto ME
Lbl JO
Text(25,22,"CHARGEMENT...
Text(32,22,"0/999
ClrList L₁
ClrList L₂
{7,22,37→L₂
999→dim(L₁
1→X
L₂(randInt(1,3→L₁(1
For(I,2,990
1+X(X≠10→X
L₂(randInt(1,3→L₁(I
If X=10
Then
While L₁(I)=L₁(I-1
L₂(randInt(1,3→L₁(I
End
End
Text(32,22,I,"/999
End
For(I,991,999
⁻1→L₁(I
Text(32,22,I,"/999
End
ClrList L₂
ClrList L₃
11→dim(L₂
11→dim(L₃
ClrDraw
{0,0,2,8,10,8,2,0→L₂
{3,11,9,9,7,5,5,3→L₃
For(I,1,7
Line(L₂(I),L₃(I),L₂(I+1),L₃(I+1
End
Horizontal 46
⁻9→S
Text(4,5,"SCORE :
Text(4,29,0
Text(4,51,"RECORD :
Text(4,79,L₆(1
1→C
0→P
10→dim(L₄
10→dim(L₅
For(I,1,10
⁻1→L₄(I
⁻1→L₅(I
End
1→W
1→Z
While C and Z<1000
S+1+(W=9)(Z>13→S
Text(4,29,S(S>0),"
getKey→K
If (K=25)(P≠2) or (K=34)(P≠0
Then
P*15→R
Text(54-R,0,"
Text(49-R,0,"
L₃+(K=25)15-15(K=34→L₃
P+(K=25)-(K=34→P
Pt-Off(5,L₃(5
For(I,1,7
Line(L₂(I),L₃(I),L₂(I+1),L₃(I+1
End
End
1+W(W≠9→X
For(I,1,10
Pt-Off(L₄(I),L₅(I
End
L₄-10→L₄
85→L₄(W
L₁(Z→L₅(W
(W=9)85+(W≠9)L₄(10→L₄(10
L₅(10)(W≠9)+(W=9)L₁(Z+(Z≠999→L₅(10
Z+1+(W=9→Z
For(I,1,10
Pt-On(L₄(I),L₅(I
End
If L₃(5)=L₅(X) or (W=8)L₃(5)=L₅(10
0→C
X→W
End
If S=990
Then
{18,26,24,24,22,20,20,18→L₃
For(I,⁻1,3
Text(54-R,10I(I≠⁻1),"
Text(49-R,10I(I≠⁻1),"
15→R
For(J,1,7
Line(L₂(J),L₃(J),L₂(J+1),L₃(J+1
End
L₂+10→L₂
End
Text(24,27,"VICTOIRE !!!
Else
Circle(5,L₃(5),2
Circle(5,L₃(5),4
End
Pause
ClrDraw
0→Z
1→P
L₆→L₁
For(I,1,3
If Z=0 and S≥L₆(P
Then
S→L₆(I
1→Z
Text(7(I-1),25,"X
Else
L₁(P→L₆(I
P+1→P
End
Text(7(I-1),0,I," : ",L₆(I
End
Text(45,0,"VOTRE SCORE : ",S
0→S
1→X
For(I,1,3
S+XL₆(I→S
.001X→X
End
S→⌊SMISS(1
Pause
ClrDraw
Goto ME
Lbl QU
ClrList L₁
ClrList L₂
ClrList L₃
ClrList L₄
ClrList L₅
ClrList L₆
DelVar S
DelVar P
DelVar C
DelVar W
DelVar X
DelVar Z
DelVar I
DelVar K
DelVar R
RecallGDB 1
DelVar GDB1
PlotsOff
ZoomRcl
RecallPic 1
DelVar Pic1
Disp
|
Si ça vous intéresse, je vous donne le lien pour le télécharger : https://tiplanet.org/forum/archives_voir.php?id=654279
EDIT : Code ajouté, c'est bien de le mettre puisque l'idée de cette section est aussi de permettre des améliorations pour le public.
|
