Forum

Catégorie : Programmes
Forum : Les programmes des internautes
Vues : 2460
Réponses : 20
Type : discussion
Etat : réponses autorisées
Avertissement :
Il s'agit d'une page optimisée pour la navigation mobile. Voir la page originale.

Programme FRUITS (Jeu)

Luffychigox le 13/11/2011 à 16:14
Salut, j'ai fait un programme ou le but est de récolter les différent fruits qui tombent en déplacant un panier (chaque fruit vaut un certain nombre de points et il faut éviter de rammasser les bogues de marron qui enlèvent des points). Le programme est un peu long (893 octets) mais c'est un bon passe temps, et aussi, c'est normal que certains fuits soient impossible à avoir, sinon, on ne perdrait jamais^^
Voilà le code:
Note: -> représente sto, # représente différent de (pas égal), * représente le signe multiplier, et ¤ représente un point fait de 5 petits carrés (allez dans le catalogue, et allez 24 fois vers le bas).

Code

:EffEcr
:Output(3,4,"CUEILLETTE
:Output(4,4,"DE FRUITS
:Output(6,4,"BY LUFFYCHIGOX
:Pause
:Lbl M
:EffEcr
:Menu(" MENU ","JOUER",J,"RECORD",R,"AIDE",A,"QUITTER",Q
:Lbl R
:EffEcr
:Output(5,4,"RECORD:
:Output(5,11,L2(1
:Pause
:Goto M
:Lbl Q
:EffEcr
:Stop
:Lbl A
:Disp "¤=CERISE=1P","°=POMME=2P","O=NOIX DE COCO","=3P","*=BOGUE (MARRON)",=-2P
:Pause
:Goto M
:Lbl J
:1->dim(L2
:10->A
:1->B
:10->C
:1->D
:0->E
:0->P
:0->N
:0->M
:9->V
:Lbl 1
:EffEcr
:Output(1,3,"I
:Output(2,3,"I
:Output(3,3,"I
:Output(4,3,"I
:Output(5,3,"I
:Output(6,3,"I
:Output(7,3,"I
:Output(8,3,"I
:Output(2,1,"V
:Output(3,1,"I
:Output(4,1,"E
:Output(5,1,"S
:Output(6,1,":
:Output(7,1,V
:Output(8,A,"U
:If D=1
:Output(B,C,"¤
:If D=2
:Output(B,C,"°
:If D=3
:Output(B,C,"O
:If D=4
:Output(B,C,"*
:If B=8 et A#C et D#4
:V-1->V
:If V=O                               (ou bien pour snap :If non(V
:Goto G
:If B=8 et A=C et D=1
:E+1->E
:If B=8 et A=C et D=2
:P+1->P
:If B=8 et A=C et D=3
:N+1->N
:If B=8 et A=C et D=4
:M+1->M
:If B=8
:Then
:1->B
:entAléat(1,8->X
:If X=1 ou X=2 ou X=3
:1->D
:If X=4 ou X=5
:2->D
:If X=6
:3->D
:If X=7 ou X=8
:4->D
:entAléat(4,16->C
:End
:B+1->B
:codeTouche->K
:If K=24 et A#4
:A-1->A
:If K=26 et A#16
:A+1->A 
:Goto 1
:Lbl G
:E+2P+3N-2M->S
:If S<0
:0->S
:If S>L2(1
:S->L2(1
:EffEcr
:Output(1,4,"GAME OVER
:Disp " ","CERISES:","POMMES:","NOIX DE COCO:","BOGUES:
:Output(3,9,E
:Output(4,8,P
:Output(5,14,N
:Output(6,8,M
:Pause
:EffEcr
:Output(3,5,"SCORE:
:Output(3,11,S
:Output(5,4,"RECORD:
:Output(5,11,L2(1
:Pause
:Goto M


Voilà^^ Dites moi ce que vous e pensez (si ils y en a qui ont eu le courage de le recopier bien sûr !)
snap le 13/11/2011 à 16:27
Quelque petites modifications pour que sa prenne moins d'octet :

Code
:EffEcr
:Output(3,4,"CUEILLETTE
:Output(4,4,"DE FRUITS
:Output(6,4,"BY LUFFYCHIGOX
:Pause
:Lbl M
:EffEcr
:Menu(" MENU ","JOUER",J,"RECORD",R,"AIDE",A,"QUITTER",Q
:Lbl R
:EffEcr
:Output(5,4,"RECORD:
:Output(5,11,L2(1
:Pause
:Goto M
:Lbl Q
:EffEcr
:Stop
:Lbl A
:Disp "¤=CERISE=1P","°=POMME=2P","O=NOIX DE COCO","=3P","*=BOGUE (MARRON)",
:Pause "=-2P            <-- on peut lui dire de dire une phrase ou un nombre après une Pause
:Goto M
:Lbl J
:1->dim(L2
:10->A
:1->B
:10->C
:1->D
:Effvar E Effvar P Effvar N Effvar M 9 -> V     <-- pas d'espaces entre les fonctions
:Lbl 1
:EffEcr
:Output(1,3,"I
:Output(2,1,"V I
:Output(3,1,"I I
:Output(4,1,"E I
:Output(5,1,"S I
:Output(6,1,": I
:Output(7,3,"I
:Output(8,3,"I
:Output(7,1,V
:Output(8,A,"U
:If D=1
:Output(B,C,"¤
:If D=2
:Output(B,C,"°
:If D=3
:Output(B,C,"O
:If D=4
:Output(B,C,"*
:If B=8 et A#C et D#4
:V-1->V
:If non(V
:Goto G
:If B=8 et A=C et D=1
:E+1->E
:If B=8 et A=C et D=2
:P+1->P
:If B=8 et A=C et D=3
:N+1->N
:If B=8 et A=C et D=4
:M+1->M
:If B=8
:Then
:1->B
:entAléat(1,8->X
:If X=1 ou X=2 ou X=3
:1->D
:If X=4 ou X=5
:2->D
:If X=6
:3->D
:If X=7 ou X=8
:4->D
:entAléat(4,16->C
:End
:B+1->B
:codeTouche->K
:max(4,min(16,A-(K=24)+(K=26 -> A
:Goto 1
:Lbl G
:E+2P+3N-2M->S
:If S<0
:EffVar S
:If S>L2(1
:S->L2(1
:EffEcr
:Output(1,4,"GAME OVER
:Disp " ","CERISES:","POMMES:","NOIX DE COCO:","BOGUES:
:Output(3,9,E
:Output(4,8,P
:Output(5,14,N
:Output(6,8,M
:Pause
:EffEcr
:Output(3,5,"SCORE:
:Output(3,11,S
:Output(5,4,"RECORD:
:Output(5,11,L2(1
:Pause
:Goto M
ashtrail le 15/11/2011 à 20:47
tres simpa l'idée, enrevanche j'ai un probleme, d'habitude je regarde attentivement et je trouve toutes mes erreur mais la y en a une que je ne trouve pas il me met erreur argument a la ligne
Code
:Menu(" MENU ","JOUER",J,"RECORD",R,"AIDE",A,"QUITTER",Q
sur le Q ??? si vous pouvez m'aidez, merci.
EDIT: en fait y a plein de trucs que j'ai bien écrit qui dé***ne je crois (sans vouloir être désobligeant) que snap a fait quelques erreur dans ça version amélioré...je vais écrire l'autre pour vérifier.
sandro le 15/11/2011 à 20:51
tel que tu le poste, il est corect ton code.
-vérifie si tu n'a pas oublié/ mis en trop des guillemets
-esssaye en supriment le ' ,"QUITER",Q ' pour voir

Sandro
ashtrail le 15/11/2011 à 21:06
Ouais justement j'ai enlevé tout ce qui avait un rapport avec le Q. Et c'est là qu'il a pas arrêter de me mettre des erreur ou j'ai tout bien écrit... Je vais donc tester l'autre version pour voir si c'est le code de snap ou ma calcu qui bugge
EDIT: j'ai rien dit la version de snap marche et en tapant les deux ça m'a fait un gros mélange qui a abouti au fait que les fruits tombent toujours du même endroit... enfin bon je vais me débrouiller...
ashtrail le 16/11/2011 à 15:37
Bon euh... qqn aurais pas une idée d'où ça pourrait venir le fait que ça tombe toujours du même endroit juste vaguement pour m'aider un peu...
The K le 16/11/2011 à 16:12
Comme ça, sans regarder dans le détail, je te dirais de vérifier toutes les lignes ou apparaissent les variables A et C, particulièrement C winkle.gif
ashtrail le 16/11/2011 à 16:24
snif,snif je ne sais pas ce que je ferais sans toi the K...
EDIT: exact j'avais confondu un O et un C ( moi de toute façon entre les O, les 0, et les C)(enfin bon j'ai des problemes d'yeux donc ça compte pas)
Ps; j'adore la touche edit...
The K le 16/11/2011 à 16:25
Eh bien tu ferais pas de CodeTouche -> K que veux tu ^^
(nan elle était pourrie la !)

Bref, à ton service winkle.gif
ashtrail le 16/11/2011 à 16:55
sinon a l'adresse de Luffychigox à la ligne :
Code
:Disp " ","CERISES:","POMMES:","NOIX DE COCO:","BOGUES:
:Output(3,9,E
:Output(4,8,P
:Output(5,14,N
:Output(6,8,M

ça bugge pas mais t'as dû te gourré parce que on obtient un truc du genre
cerises:...
pommes:2
noix de5coco:...
bogues: 2
3
voila voila pas besoin de me dire comment l'arranger je peux le faire tout seul mais pour les "débutant"(oui,je sais j'en suis un aussi mais bon) qui vont recopier le code ...

PS:
Code
:Output(3,4,"CUEILLETTE
:Output(4,4,"DE FRUITS
:Output(6,4,"BY LUFFYCHIGOX

tu peux mettre
Code
output(3,3,"ceuill...
output(4,4,"de fr..
output(6,3,"luffy...

c'est plus joli... minied.gif
Persalteas le 16/11/2011 à 23:13
tu les trouves où, le f et le y minuscule ?
ashtrail le 18/11/2011 à 18:05
Glups... euh... puis-je t'avouer que je suis un gros flemmard qui n'a même pas pris la peine de le mettre en majuscule... si ça te pertube je peux l'editer...
gcasse le 19/11/2011 à 12:05
Salut à tous,

J'ai eu, comme vous dites, le "courrage" de recopier entièrement le primier programme proposé, et j'ai une question : qu'est-ce qui varie le fait qu'on perde le jeu ou non ? le fait qu'on prenne pas tous les fruits peut-être ? ou les bogues qu'on se prend non ? frozen.gif
The K le 19/11/2011 à 13:07
On arrête le jeu quand la variable V atteint 0. Dans le détail, c'est quand tu as laissé tomber hors de ton panier 8 ou 9 fruits autres que des bogues.
Thibaud-sans'ID le 19/11/2011 à 13:47
Bonjour a tous et a toutes,

Dans ton premier prgm , (que j'ai tapé sur ma calculette) , j'ai tout bien tapé ,j'ai réussi a joué mais au bout d'un moment sa met ERR:DOMAINE 1:Quitter
2:Voir
Je vais dans voir et a la ligne :

Output(8,A,"U

Pouvez vous m'aider merci beaucoup eyeonly.gif moodforlove.gif
The K le 19/11/2011 à 14:00
Vérifie bien que tu as rentré 10->A sur les lignes précédentes ... sinon, regarde toutes les lignes ou la variable A est présente winkle.gif
gcasse le 19/11/2011 à 14:27
Merci, mais je m'en était justement rendu compte quand j'ai un peu modifié ce programme. Notez qu'il y a une erreur :

-il faut une ligne entre la ligne 18 et 19 (Lbl A et Disp cerises ...)
où il serait simplement écrit "EffEcr" bigmouth.gif

Voila, sinon, quand vous allez dans record, le texte normalement affiché dans ce menu sera en fait affiché par dessus ce qu'il y avait dans le menu précédent
Et ça fait des lettres et des chiffres un peu nimporte où happy.gif

Et j'avais posé cette question tout à l'heure parce que dans le jeu, il y avait marqué en vertical "VIES:V", mais c'est bon j'ai trouvé mon erreur. laugh.gif

Merci
Thibaud-sans'ID le 19/11/2011 à 19:29
Merci
Juste une question ,
Comment fais-t-on les # ? moi j'ai fais des =/= c'est pareil ou pas?


Merci crazy.gif
The K le 19/11/2011 à 19:32
=/=, comme égal diviser égal ? Non.
# est égal au signe "différent de", que l'on trouve en seconde position dans le menu test. Une autre de ses notations est en effet =/=, mais comme je ne sais pas si tu l'as écrit au caractère près ou sa signification bah ... ^^'
Thibaud-sans'ID le 19/11/2011 à 19:33
Merci oui en fait j'ai écrit comme différent de
eyeonly.gif
ashtrail le 23/11/2011 à 18:25
Voila j'ai fait les modifs ça donne:
Code
:Disp " ","CERISES:","POMMES:","NOIX DE COCO:","BOGUES:
:Output(2,9,E
:Output(3,8,P
:Output(4,14,N
:Output(5,8,M

Edite ton code Luffychigox
Avertissement :
Il s'agit d'une page optimisée pour la navigation mobile. Voir la page originale.