Je vais vous présenter mon programme de solitaire qui fait 808 octets. La source est en français, je vous donne la traduction en bas
Je ne vous propose pas de .8xp car je ne sais pas comment faire... Par contre si quelqu'un m'explique ou me donne un tuto, je suis preneur =D (je n'ai pas de cable mais j'ai entré tout le programme dans VTI
Code
:EffEcr
:[[2,2,1,1,1,2,2][2,1,1,1,1,1,2][1,1,1,1,1,1,1][1,1,1,0,1,1,1][1,1,1,1,1,1,1][2,1,1,1,1,1,2][2,2,1,1,1,2,2]]->[A]
:{4,4}->L1
:{4,4}->L2
:0->A:1->B:10->C:36->D
:Output(7,9,"RESTE 36
:Output(8,10,"BILLES
:For(I,1,7
:For(J,1,7
:If [A](I,J)=1:Output(I,J,"O
:End:End
:Lbl A
:0->K
:Output(8,L2(1)," "
:Output(8,L1(1),"^
:L1(1)->L2(1)
:Output(L2(2),8," "
:Output(L1(2),8,"<
:L1(2)->L2(2)
:codeTouche->K
:L1(1)-(K=24 et L1(1)>1)+(K=26 et L1(1)<7)->L1(1)
:L1(2)-(K=25 et L1(2)>1)+(K=34 et L1(2)<7)->L1(2)
:If K=105 et A=0:Goto 1
:If K=105 et A=1:Goto 2
:Goto A
:Lbl 1
:If [A](L1(2),L1(1))=1:Then
:1->A
:Output(L1(2),L1(1),"X
:L1(1)->Y:L1(2)->X
:End
:Goto A
:Lbl 2
:If X-2=L1(2) et Y=L1(1) ou X+2=L1(2) et Y=L1(1) ou Y-2=L1(1) et X=L1(2) ou Y+2=L1(1) et X=L1(2)
:Then
:(L1(2)+X)/2->E
:(L1(1)+Y)/2->F
:If [A](L1(2),L1(1))=0 et [A](E,F)=1:Then
:0->[A](E,F)
:Output(E,F," "
:0->[A](X,Y)
:Output (X,Y," "
:1->[A](L1(2),L1(1))
:Output(L1(2),L1(1),"O
:Output(B,C,"O
:C+1->C
:If C=17:Then
:10->C:B+1->B
:End
:D-1->D
:Output(7,15," "
:Output(7,15,D
:0->A
:End:End
:If L1(2)=X et L1(1)=Y:Then
:0->A
:Output(X,Y,"O
:End
:Goto A
Le programme n'a pas de bug mais il est possible que je fasse une ou deux erreurs de recopiage (et vous aussi ^^). Si vous avez des idées d'améliorations, n'hésitez pas à proposer, merci
